Formel VBA för pivottabells senaste uppdatering

Först publicerad:

| © ExcelKungen.com

Att hålla reda på en pivottabells senaste uppdatering kan vara avgörande, särskilt när du arbetar med data som ofta förändras. I den här artikeln kommer vi att gå igenom hur du kan använda en VBA-funktion för att få datum och tid för den senaste uppdateringen av din pivottabell.

Varför är det viktigt att veta när en pivottabell uppdaterades?

Pivottabeller är kraftfulla verktyg för dataanalys och rapportering, men det är viktigt att veta om din information är aktuell eller ej. Genom att använda en funktion för att spåra en pivottabells senaste uppdatering kan du:

  • Förbättra datakvalitet: Säkerställ att du alltid arbetar med den senaste informationen.
  • Öka effektiviteten: Automatisera uppdateringsprocessen och spar tid.
  • Underlätta samarbete: Informera kollegor om när data senast bearbetades.

Vidare kan detta vara användbart när man har automatisk uppdatering av pivottabeller avslagen. Generell information angående uppdateringar av pivottabeller får du på Uppdatera Pivottabeller i Excel.

VBA-kod kan fånga tiden för senaste uppdatering

Nedan följer en VBA-kod som du kan använda i din Excel-fil för att få information om senaste uppdatering av en pivottabell:


Public Function PivUppdaterad(rngCell As Range) As Variant
'--------------------------------------------------------------------
' Funktionen återger tidpunkt för pivottabellens senaste uppdatering
' =PivUppdaterad(A10) skriver ut pivottabellens senaste uppdatering,
' t ex "2015-12-04 [10:28:38]"
' (c) ExcelKungen.com
'--------------------------------------------------------------------
Dim pivotTabell As PivotTable
Dim strTimestamp() As String 'matrisvariabel för (0) datum, (1) tid
Dim strDatum As String
Dim strTidpunkt As String

On Error Resume Next

'referens till pivottabellen
Set pivotTabell = rngCell.Cells(1, 1).PivotTable

If Err.Number = 0 Then
 'tar fram och formaterar datum och klockslag
   strTimestamp = Split(pivotTabell.RefreshDate, " ") 'splittar datum & tid
   strDatum = Format(strTimestamp(0), "YYYY-MM-DD") 'formaterar datumet
   strTidpunkt = Format(strTimestamp(1), "hh:mm:ss;@") 'formaterar tid
 'svarsmeddelande sätts ihop
 PivUppdaterad = strDatum & " [" & strTidpunkt & "]"
Else
 'meddelande om fel uppstår
  PivUppdaterad = "Error: Cellreferensen ej pivottabell."
End If

End Function

Steg-för-steg guide: Implementera VBA-koden

  • Öppna din arbetsbok i Excel.
  • Tryck på ALT + F11 för att öppna VBA-editorn.
  • Infoga en ny modul genom att högerklicka på ditt arbetsboknamn i Projektfönstret, välj "Infoga" och sedan "Modul".
  • Kopiera och klistra in koden ovan i den nya modulen.
  • Stäng VBA-editorn och gå tillbaka till ditt kalkylblad.
  • Använd formeln =PivUppdaterad(A10) (där t.ex. A10 är cellen som innehåller din pivottabell).
=PivUppdaterad(A10)

Visuellt exempel: Pivottabells senaste uppdatering

I bilden nedan ser vi hur vi med hjälp av denna VBA-funktion kan skriva ut tidpunkten för en pivottabells senaste uppdatering. Vi kan snabbt kontrollera när data senast bearbetades utan att behöva gräva igenom menyer och inställningar.

Formel som visar en pivottabells tidpunkt för senaste uppdatering.

Avslutande tankar

Att spåra senaste uppdatering av en pivottabell kan spara tid och öka datakvaliteten i dina Excel-rapporter. Genom att använda den här enkla VBA-funktionen får du en snabb och effektiv översikt över när dina pivottabeller senast uppdaterades.

Populära artiklar

Dagens tips

Relaterade artiklar